***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jul 23, 2024                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt PEC3836C2C-AU 1 2
.param
+vc0 = 2.111e-10	         vc1 = 2.885e-12   	 vc2 = 0.800		 vc3 = 4.291e-11		 vc4 = 5.630e-2
+tc1 = 4.381e-2	         tc2 = 3.221e-2		 tc3 = 6.091e-3		 tc4 = 4.801e-2 
.func irexp(v) {(vc0+vc1*v**vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 1 C zener
g1 C 1 value = {irexp(v(C,1))}
d2 2 C zener
g2 C 2 value = {irexp(v(C,2))}
.model zener d
***** flag parameter *****
+level = 1                     
***** dc model parameter *****
+ is = 1e-15	 n = 1		  rs = 1.000e-3
+ibv = 1e-3		 nbv = 1e-3		  bv = 44.30
***** capacitance parameter *****
+cjo = 1.280e-11	   m = 1.618e-1		  vj = 1.421
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 0.75		 xti = 3
+trs1 = 1e-3	  tbv1 = 8.637e-4  tbv2 = -1.017e-6
.ends PEC3836C2C-AU
*$
